data "aws_iam_policy_document" "ecs_assume_role" {
  statement {
    sid     = "AllowAssumeRoleFromECSTasks"
    effect  = "Allow"
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["ecs-tasks.amazonaws.com"]
    }
  }
}

data "aws_iam_policy_document" "network_auth_task_role" {

  statement {
    sid = "NetworkAuthSecretsAccess"
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]
    resources = [
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:mysql_pass_network_auth_server-??????",
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:network_auth-service-client-secret-??????"
    ]
  }

  statement {
    sid = "NetworkAuthServiceSecrets"
    effect = "Allow"
    actions = ["secretsmanager:*"]
    resources = ["*"]
  }
  statement {
    sid = "neteworkAuthECSTaskExecution"
    effect = "Allow"
    actions = [
      "ecr:GetAuthorizationToken",
      "ecr:BatchCheckLayerAvailability",
      "ecr:GetDownloadUrlForLayer",
      "ecr:BatchGetImage",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
    resources = ["*"]
  }

}


resource "aws_iam_policy" "network_auth_task_role" {
  name = "${var.service_name}${local.workspace["iam_suffix"]}"
  policy = data.aws_iam_policy_document.network_auth_task_role.json
}

resource "aws_iam_role" "network_auth_task_role" {
  name = "${var.service_name}-task-role${local.workspace["iam_suffix"]}"
  assume_role_policy = data.aws_iam_policy_document.ecs_assume_role.json
}

resource "aws_iam_role_policy_attachment" "network_auth_task_role_policy_attach" {
  role = aws_iam_role.network_auth_task_role.name
  policy_arn = aws_iam_policy.network_auth_task_role.arn
}


resource "aws_iam_role_policy_attachment" "profile_internal_policy_attach" {
  role = aws_iam_role.network_auth_task_role.name
  policy_arn = aws_iam_policy.internal_profile_policy_copy.arn
}

resource "aws_iam_policy" "internal_profile_policy_copy" {
  name = "${var.service_name}-profile-internal${local.workspace["iam_suffix"]}"
  policy = data.terraform_remote_state.mop_core.outputs.tf_profile_internal_policy_document
}

#
##
### if Sandbox then create a user with the same policies for localhost MOP
##
#

# create an IAM user for the localhost service
resource "aws_iam_user" "network_auth_service" {
  name = "network_auth_service"
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}
# this credential lives in sandbox-credentials
resource "aws_iam_access_key" "network_auth_service" {
  user = aws_iam_user.network_auth_service[0].name
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}

# attach the same policies held by the task role
resource "aws_iam_user_policy_attachment" "profile_internal_network_auth" {
  user       = aws_iam_user.network_auth_service[0].name
  policy_arn = aws_iam_policy.internal_profile_policy_copy.arn
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}
resource "aws_iam_user_policy_attachment" "task_role_network_auth" {
  user       = aws_iam_user.network_auth_service[0].name
  policy_arn = aws_iam_policy.network_auth_task_role.arn
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}




### KMS Permission Block Start ###

data "aws_iam_policy_document" "network_auth_kms_policy_doc" {
  statement {
    sid = "NetworkAuthKMSPermissions"
    effect = "Allow"
    actions = [
      "kms:*"
    ]
    resources = [ "arn:aws:kms::${data.aws_caller_identity.current.account_id}:alias/network-*" ]
  }
}

resource "aws_iam_policy" "network_auth_kms_policy" {
  name = "${var.service_name}-kms-policy${local.workspace["iam_suffix"]}"
  policy = data.aws_iam_policy_document.network_auth_kms_policy_doc.json
}

resource "aws_iam_user_policy_attachment" "network_auth_kms_policy_attachment" {
  user       = aws_iam_user.network_auth_service[0].name
  policy_arn = aws_iam_policy.network_auth_kms_policy.arn
  count = local.deploy_env_name == "sandbox" ? 1 : 0
}

### KMS Permission Block End ###